Термодинамические расчеты в электронных таблицах в составе учебного мультимедийного комплекса, страница 13

6. Кубашевский О., Олкокк С.Е. Металлургическая термохимия. М.: Металлургия, 1982. 391 с.

7. Моисеев Г.К., Ватолин Н.А. и др. Температурные зависимости приведенной энергии Гиббса некоторых неорганических веществ (альтернативный банк данных АСТРА.OWN). Екатеринбург: УРО РАН, 1997. 230 с.

8. Додж М., Кината К., Стинсон К. Эффективная работа с Excel 7.0 для Windows 95 / Перев. с англ. СПб.: Питер, 1996. 1040 с.: ил.


Приложение

Тексты специальных функции для расчета термодинамических свойств при высоких температурах

Option Explicit

Const T0 = 298.15

Const RG = 8.31441

Dim DataArea As Range

Dim RecFile As Integer

Dim FileName As String

Function RUG () As Single

'Функция возвращает значение универсальной газовой постоянной

RUG = RG

End Function

Function SInT(Tini, Tnxt, b As Range) As Single

'Функция возвращает изменение энтропии при нагреве вещества от Tini до 'Tnxt, коэффициенты температурной зависимости теплоемкости- b

Dim j As Integer

SInT = Log(Tnxt / Tini) * b.Cells(2)

For j = -2 To 3

   If Not (j = -1 Or j = 0) Then SInT = SInT + _

      (Tnxt ^ j - Tini ^ j) / j * b.Cells(j + 2 - (j = -2))

Next

End Function

Function HInT(Tini, Tnxt, b As Range) As Double

'Функция возвращает изменение энтальпии при нагреве вещества от Tini до 'Tnxt, коэффициенты температурной зависимости теплоемкости- b

Dim j As Integer

HInT = 0

For j = -1 To 4

  If Not j = 0 Then HInT = HInT + (Tnxt ^ j - Tini ^ j) / j * b.Cells(j + 1 - (j = -1))

Next

End Function

Function SFT(S298 As Single, Tx As Single, M As Range) As Single

'Функция возвращает значение ЭНТРОПИИ вещества при нагреве от 298.15 'К до заданной температуры Tx с учетом всех полиморфных превращений в 'этом интервале.

'Возможен расчет до состояния переохлажденной жидкости

Dim i As Integer: Dim j As Integer: Dim k As Integer

Dim T As Single: Dim Ti As Single

T = T0: SFT = S298

For k = 1 To M.Cells.Rows.Count

   Ti = T

   If k = M.Cells.Rows.Count Then T = Tx Else T = M.Cells(k, 6)

   SFT = SFT + Log(T / Ti) * M.Cells(k, 2)

   For i = -2 To 3

      If Not (i = -1 Or i = 0) Then _

                     SFT = SFT + (T ^ i - Ti ^ i) / i * M.Cells(k, i + 2 - (i = -2))

   Next

   If k < M.Cells.Rows.Count Then SFT = SFT + M.Cells(k, 7)

Next

End Function

Function HFT(H298 As Single, Tx As Single, M As Range) As Single

'Функция возвращает значение изменения ЭНТАЛЬПИИ вещества при заданной температуре Tx с учетом всех полиморфных превращений в 'интервале 298.15 – Тх. Возможен расчет до состояния переохлажденной жидкости

Dim i As Integer: Dim j As Integer: Dim k As Integer

Dim T As Single: Dim Ti As Single

T = T0: HFT = H298

For k = 1 To M.Cells.Rows.Count

   Ti = T

   If k = M.Cells.Rows.Count Then T = Tx Else T = M.Cells(k, 6)

   For j = -1 To 4

      If Not j = 0 Then HFT = HFT + (T ^ j - Ti ^ j) / j * M.Cells(k, j + 1 - (j = -1))

   Next

   If k < M.Cells.Rows.Count Then HFT = HFT + M.Cells(k, 7) * M.Cells(k, 6)

Next

End Function

Function GFT(H298 As Single, S298 As Single, Tx As Single, M As Range) As Single

'Функция возвращает значение изменения ЭНЕРГИИ ГИББСА вещества 'при заданной температуре Tx с учетом всех полиморфных превращений в 'интервале 298.15 – Тх. Возможен расчет до состояния переохлажденной 'жидкости

Dim i As Integer: Dim j As Integer: Dim k As Integer

Dim S As Single

Dim T As Single: Dim Ti As Single

T = T0: S = S298: GFT = H298 - T0 * S

For k = 1 To M.Cells.Rows.Count

   Ti = T

   If  k = M.Cells.Rows.Count Then T = Tx Else T = M.Cells(k, 6)

   GFT = GFT - (S - M.Cells(k, 2)) * (T - Ti) - T * Log(T / Ti) * M.Cells(k, 2)

   S = S + Log(T / Ti) * M.Cells(k, 2)

   For i = -2 To 3

     If Not (i = -1 Or i = 0) Then

       j = i + 2 - (i = -2)

       S = S + (T ^ i - Ti ^ i) / i * M.Cells(k, j)

     GFT = GFT - (T ^ (i + 1) - (T + i * (T - Ti)) * Ti ^ i) / i / (i + 1) * M.Cells(k, j)

     End If

   Next

   If k < M.Cells.Rows.Count Then S = S + M.Cells(k, 7)

Next

End Function


Методическое пособие

в составе мультимедийного комплекса

А.М. Панфилов, Н.С. Лямкина

ТЕРМОДИНАМИЧЕСКИЕ РАСЧЕТЫ

В ЭЛЕКТРОННЫХ ТАБЛИЦАХ